Moving MICS data to z/OS.

To move the data collected for MICS from the ZVPS collection to z/OS requires the following:
Note: This procedure will need to be updated to meet installation requirements.

The most optimal method is to have the files created each hour - which is the default. At midnight, have a process group the files into one single file to be FTP'd to z/OS for MICS processing.

The MAPGOOD EXEC needs to be copied to the "A" disk. There is a sample on the product disk.
This EXEC needs to have the following line added: 'EXEC ESAMICS'

This is an example of the contents of a proposed ESAMICS EXEC:

 
/*----------------------------------------------------------*/
/*                                                          */
/* S A M P L E                                              */
/*                                                          */
/* exec to copy yesterday's mics files to esamap work disk  */
/*----------------------------------------------------------*/
 
/*----------------------------------------------------------*/
/* Retrieve all ESAEXTR file except today's                 */
/*----------------------------------------------------------*/
 
  ft = DATE('S')
  today=substr(ft,5,4)
 
  'PIPE CMS LISTFILE ESAEXTR * J (NOH',
    '| nfind ESAEXTR  FILE',
    '| nlocate /'||today||'/',
    '| sort w2'         ,
    '| stem files.'     ,
    '| getfiles'        ,
    '| > ESAEXTR' ft 'K'
 
/*----------------------------------------------------------*/
/* If successfully retrieve, ERASE source files             */
/*----------------------------------------------------------*/
 
  If rc = 0 Then
    'pipe stem files.',
      '| spec \ERASE\ 1 w1.3 nw',
      '| console',
      '| spec \SMSG ESASERVE CMS\ 1 W1-* NW',
      '| cp'
 
/*----------------------------------------------------------*/
/* Set target ZOS system target variables                   */
/*----------------------------------------------------------*/
 
  ZOS          = '192.168.1.0'       /* Target IP address   */
  Myid         = 'George'            /* Authorized userid   */
  Mypswd       = 'Jungle'            /* Password            */
  zosdirectory = 'abc.def'           /* Target directory    */
 
/*----------------------------------------------------------*/
/* Send file to ZOS via FTP                                 */
/*----------------------------------------------------------*/
 
  fileid = 'ESAEXTR.' || ft
 
  queue myid mypswd                  /* Stack ID and PSWD   */
  queue 'cd' ||,
      "'" || zosdirectory || "'"     /* ... target directory*/
  queue 'mode b'                     /* ... BLOCK mode      */
  queue 'type e'                     /* ... EBCDIC          */
  queue 'lcd k'                      /* ... Local FM 'K'    */
  queue 'put' fileid                 /* ... PUT the file    */
  queue 'quit'                       /* ... then QUIT       */
  'FTP' ZOS                          /* Issue FTP           */
 
/*----------------------------------------------------------*/
/* If successful then erase source file                     */
/*----------------------------------------------------------*/
 
  cc = rc
 
  If rc = 0 then
    'ERASE ESAEXTR' FT 'K'
  Else
    Say '*** Error *** RC' RC 'from FTP to -',
      ZOS '>' zosdirectory
 
Exit cc