Moving MXG data to z/OS.

To move the data collected for MXG from the ZVPS collection to z/OS requires the following:
Note: This procedure will need to be updated to meet installation requirements.

MXG is capable of reading the HISTORY files created by ZVPS. The midnight processing of ZMAP collects the days worth of data and summarizes that data into installation defined intervals. Upon successful completion the MAPGOOD EXEC will be invoked.

The MAPGOOD EXEC needs to be copied to the "A" disk. There is a sample on the product disk.
This EXEC needs to have the following line added: 'EXEC ESAMXG'

Here is an example of the contents of a proposed ESAMXG EXEC

 
/*----------------------------------------------------------*/
/*                                                          */
/* S A M P L E                                              */
/*                                                          */
/* exec to send selected history files to ZOS               */
/*----------------------------------------------------------*/
 
/*----------------------------------------------------------*/
/* Set target ZOS system target variables                   */
/*----------------------------------------------------------*/
 
  ZOS          = '192.168.1.0'       /* Target IP address   */
  Myid         = 'George'            /* Authorized userid   */
  Mypswd       = 'Jungle'            /* Password            */
  zosdirectory = 'abc.def'           /* Target directory    */
 
/*----------------------------------------------------------*/
/* Send file to ZOS via FTP                                 */
/*----------------------------------------------------------*/
 
  queue myid mypswd                  /* Stack ID and PSWD   */
  queue 'cd',
      "'" || zosdirectory || "'"     /* ... target directory*/
  queue 'mode b'                     /* ... BLOCK mode      */
  queue 'type e'                     /* ... EBCDIC          */
 
/*----------------------------------------------------------*/
/* Get the list of HISTORY files to ship                    */
/*----------------------------------------------------------*/
 
  ShipList = 'ESASYS ESACPU ESAUSR ESADEV ESATCP'
  'PIPE VAR SHIPLIST',
    '| SPLIT AT BLANK',
    '| JOIN * \/ ! /\',
    '| VAR SHIPLIST'
 
  'PIPE CMS LISTFILE * HISTORY A (NOH',
    '| SPEC W1.2 1',
    '| ALL /' || SHIPLIST || '/',
    '| spec \put\ 1 w1 nw \.\ n w2 n',
    '| stack fifo'
 
  queue 'quit'                       /* ... then QUIT       */
  'FTP' ZOS                          /* Issue FTP           */
 
  If rc <> 0 then
    Say '*** Error *** RC' RC 'from FTP to -',
      ZOS '>' zosdirectory
 
Exit rc